Salve salve....
Ponto de entrada FINALEG- ( Financeiro - Várias)
FINXFIN-FINALEG - Utilizado para alterar as legendas de diversas rotinas do financeiro como FINA040, FINA050, FINA740, FINA750, FINA281
#INCLUDE "TOTVS.CH"
/*/{Protheus.doc} FINALEG
Utilizado para alterar as legendas de diversas rotinas do financeiro como FINA040, FINA050, FINA740, FINA750, FINA281
@type function
@author Eurai Rapelli
@since 2023.01.01
/*/
User Function FINALEG()
Local nReg := PARAMIXB[1]
Local cAlias := PARAMIXB[2]
Local uRetorno := {}
Local aLegenda := { {"BR_VERDE" , "Titulo em aberto" },; // "Titulo em aberto" [1][1]
/*******************/{"BR_AZUL" , "Baixado parcialmente" },; // "Baixado parcialmente" [2][1]
/*******************/{"BR_VERMELHO" , "Titulo baixado" },; // "Titulo Baixado" [3][1]
/*******************/{"BR_PRETO" , "Titulo em bordero" },; // "Titulo em Bordero" [4][1]
/*******************/{"BR_BRANCO" , "Adiantamento com saldo" } } // "Adiantamento com saldo" [5][1]
If(nReg == Nil) // Chamada direta da funcao onde nao passa, via menu Recno eh passado
uRetorno := {}
If(cAlias == "SE1")
aAdd(aLegenda, {"BR_AMARELO" , "Titulo protestado"}) //"Titulo Protestado" [6][1]
aAdd(uRetorno, { 'ROUND(E1_SALDO,2) = 0', aLegenda[3][1] } )
aAdd(uRetorno, { 'E1_TIPO == "'+MVRECANT+'".and. ROUND(E1_SALDO,2) > 0', aLegenda[5][1] } )
aAdd(uRetorno, { '!Empty(E1_NUMBOR)', aLegenda[4][1] } )
aAdd(uRetorno, { 'ROUND(E1_SALDO,2) # ROUND(E1_VALOR,2)', aLegenda[2][1] } )
aAdd(uRetorno, { 'ROUND(E1_SALDO,2) == ROUND(E1_VALOR,2) .and. E1_SITUACA == "F"', aLegenda[6][1] } )
aAdd(uRetorno, { '.T.', aLegenda[1][1] } )
Else
IF !Empty(GetMv("MV_APRPAG")) .or. GetMv("MV_CTLIPAG")
aAdd(aLegenda, { "BR_AMARELO", "Titulo aguardando liberacao"}) //Titulo aguardando liberacao
aAdd(uRetorno, { ' EMPTY(E2_DATALIB) .AND. (SE2->E2_SALDO+SE2->E2_SDACRES-SE2->E2_SDDECRE) > GetMV("MV_VLMINPG") .AND. E2_SALDO > 0', aLegenda[6][1] } )
EndIf
aAdd(uRetorno, { 'E2_TIPO == "'+MVPAGANT+'" .and. ROUND(E2_SALDO,2) > 0', aLegenda[5][1] } )
aAdd(uRetorno, { 'ROUND(E2_SALDO,2) + ROUND(E2_SDACRES,2) = 0', aLegenda[3][1] } )
aAdd(uRetorno, { '!Empty(E2_NUMBOR)', aLegenda[4][1] } )
aAdd(uRetorno, { 'ROUND(E2_SALDO,2)+ ROUND(E2_SDACRES,2) # ROUND(E2_VALOR,2)+ ROUND(E2_ACRESC,2)', aLegenda[2][1] } )
aAdd(uRetorno, { '.T.', aLegenda[1][1] } )
Endif
Else
If(cAlias == "SE1")
Else
IF !Empty(GetMv("MV_APRPAG")) .or. GetMv("MV_CTLIPAG")
Aadd(aLegenda, {"BR_AMARELO", "Titulo aguardando liberacao"}) //Titulo aguardando liberacao
EndIf
Endif
BrwLegenda(cCadastro, "Legenda", aLegenda)
Endif
Return(uRetorno)
Gostou? Compartilhe com seus amigos e deixe um comentário! 😎
Um abraço, e até a próxima