Salve salve....
Ponto de entrada MT160WF- ( Compras / Cotação )
MATA160-MT160WF - Gravação de campos adicionais no pedido (Cotação)
#INCLUDE "TOTVS.CH"
/*/{Protheus.doc} MT160WF
Gravação de campos adicionais no pedido (Cotação)
@type function
@author Eurai Rapelli
@since 2023.01.01
/*/
User Function MT160WF()
Local aArea := GetArea()
Local aAreaSC7 := SC7->( GetArea() )
Local cFilialSC7 := xFilial("SC7")
Local cFilialSC8 := xFilial("SC8")
Local cCRLF := CRLF
Local cC8NUM := PARAMIXB[01]
If Select("QryUDSC8") > 0//Verifica se ja existe alias criado
QryUDSC8->( dbCloseArea() )
Endif
cQuery := cCRLF + " SELECT DISTINCT "
cQuery += cCRLF + " C8_NUMPED "
cQuery += cCRLF + " FROM "
cQuery += cCRLF + RetSqlName("SC8") + " SC8 "
cQuery += cCRLF + " WHERE "
cQuery += cCRLF + " C8_FILIAL = '" + cFilialSC8 + "' "
cQuery += cCRLF + " AND C8_NUM = '" + cC8NUM + "' "
cQuery += cCRLF + " AND C8_NUMPED <> 'XXXXXX' "
cQuery += cCRLF + " AND SC8.D_E_L_E_T_ = '' "
MPSysOpenQuery(cQuery,'QryUDSC8')
Do While QryUDSC8->( !EOF() )
Begin Sequence
If Empty( QryUDSC8->C8_NUMPED )
Break
Endif
If !SC7->( dbSeek( cFilialSC7 + QryUDSC8->C8_NUMPED ) )
Break
Endif
Do While SC7->( !EOF() ) ;
.AND. SC7->C7_FILIAL == cFilialSC7 ;
.AND. SC7->C7_NUM == QryUDSC8->C8_NUMPED
If RecLock("SC7", .F.)
SC7->C7_XX := 'EURAI'
SC7->( MsUnlock() )
Endif
SC7->( dbSkip() )
EndDo
End Sequence
QryUDSC8->( dbSkip() )
EndDo
QryUDSC8->( dbCloseArea() )
RestArea( aAreaSC7 )
RestArea( aArea )
Return( Nil )
Gostou? Compartilhe com seus amigos e deixe um comentário! 😎
Um abraço, e até a próxima