SPEDFISCAL-SPED1601 - Gerar o registro 1601

Salve salve....

Ponto de entrada SPED1601- ( Sped Fiscal )

SPEDFISCAL-SPED1601 - Gerar o registro 1601   

#INCLUDE "TOTVS.CH"


/*/{Protheus.doc} SPED1601
Gerar o registro 1601 no Sped Fiscal quando não há integração com o módulo SIGALOJA

@type 		function
@author    	Eurai Rapelli
@since     	2023.01.01
/*/
User Function SPED1601()
Local aReg1601  := {} as array
Local aTmp      := {} as array
Local dDataDe   := Iif(Len(ParamIXB) >= 1 , ParamIXB[1], ctod("  /  /  ")) as date
Local dDataAte  := Iif(Len(ParamIXB) >= 2 , ParamIXB[2], ctod("  /  /  ")) as date
Local cQuery    := "" as character


// COD_PART_IP - COD_PART_IT - TOT_VS - TOT_ISS - TOT_OUTROS
// Exemplo do Array
// aAdd (aReg1601, {"CODIGO_CLIENTE_ADM_CARTAO","CODIGO_INTERMEDIADOR",0,0,0})
// OBS:
// COD_PART_IP: O valor informado deve existir no campo COD_PART do registro 0150.
// COD_PART_IT: O valor informado deve existir no campo COD_PART do registro 0150.
// TOT_VS : o valor deve ser preenchido com o total bruto de vendas que tiveram escrituração de ICMS , inclusive como ICMS Isento ou Outros
// TOT_ISS: o valor deve ser preenchido com o total bruto de prestação de serviços que tiveram incidência de ISS.
// TOT_OUTROS : o valor de ser preenchido com o total bruto das operações que não estejam no campo de incidência do ICMS ou ISS.

/*
No modulo SIGAFAT não há o controle de Administradoras de Cartão para poder fazer amarração, portanto a ideia é fazer um DEPARA com a condição de pagamento
e ter um registro na tabela SA1 que corresponda a operadora.
Ex.: Foi criado a Condição de Pagamento "002" que corresponde as vendas de Cartão de Credito, também foi criado um registro na tabela SA1 com as informações
da operadora de Cartão de Credito.
Sugestão para montagem da Consulta no banco de Dados:
*/
    
cQuery := " SELECT "
cQuery += "     F2_FILIAL AS FILIAL,"
cQuery += "     AE_CODCLI + AE_LOJCLI AS COD_PART_IP,"
cQuery += "     F2_CODA1U AS INTERMEDIADOR,"
cQuery += "     CASE WHEN SUM(SF2.F2_VALICM) <> 0 THEN SUM(F2_VALBRUT) ELSE 0 END AS TOT_VS,"
cQuery += "     CASE WHEN SUM(SF2.F2_VALISS) <> 0 THEN SUM(F2_VALBRUT) ELSE 0 END AS TOT_ISS,"
cQuery += "     CASE WHEN SUM(SF2.F2_VALISS) = 0 AND SUM(SF2.F2_VALICM)= 0 THEN SUM(F2_VALBRUT) ELSE 0 END AS TOT_OUT "
cQuery += " FROM " + RetSQLName("SF2") + " SF2 "

cQuery += " INNER JOIN " + RetSQLName("SAE") + " SAE "
cQuery += " ON "
cQuery += "     AE_FILIAL           = '" + xFilial("SAE") + "'"
cQuery += "     AND SAE.AE_COD      = F2_COND "
cQuery += "     AND SAE.D_E_L_E_T_  = ' ' "

cQuery += " WHERE "
cQuery += "     F2_EMISSAO BETWEEN '" + Dtos(dDataDe) + "' AND '" + Dtos(dDataAte) + "' "
cQuery += "     AND SF2.D_E_L_E_T_ = ' ' "

cQuery += " GROUP BY F2_FILIAL, AE_CODCLI, AE_LOJCLI, F2_CODA1U "

cAliasTrb := MPSysOpenQuery(cQuery)

Do While (cAliasTrb)->( !EOF() )

    // Fica a critério do cliente a melhor maneira de realização a amarração dos cadastros
    // No entanto, deve-se observar que esta informação deve ser enviada com o código do CLIENTE + LOJA com todos os caracteres

    aTmp    := {}
    aAdd( aTmp, (cAliasTrb)->FILIAL )
    aAdd( aTmp, (cAliasTrb)->COD_PART_IP )   // "C09   01" // CODIGO + LOJA -> AE_CODCLI + AE_LOJCLI
    aAdd( aTmp, (cAliasTrb)->INTERMEDIADOR )  
    aAdd( aTmp, (cAliasTrb)->TOT_VS )   
    aAdd( aTmp, (cAliasTrb)->TOT_ISS )
    aAdd( aTmp, (cAliasTrb)->TOT_OUT )   

    aAdd( aReg1601, aTmp )
        
    (cAliasTrb)->( dbSkip() )
EndDo
(cAliasTrb)->( dbCloseArea() )



Return( aReg1601 )

Gostou? Compartilhe com seus amigos e deixe um comentário! 😎  

Um abraço, e até a próxima